Here's a variant with provisions to convert the part to a clip-in piece. Not sure if this would work without having a tub cover in front of me...
Maytag tub light window A806
- Thread starter hobbyapocalypse
- Start date
Help Support :
Code for the above:
// ===================================================================================
// Replacement Maytag A806 Washing Machine Tub Light Window
// (Maytag Part Number 211723)
// See this formum thread for details:
// "Maytag tub light window A806"
// https://www.automaticwasher.org/cgi-bin/TD/TD-VIEWTHREAD.cgi?81875_15~1
// ===================================================================================
// Model version: 2
// Change log:
// v1: Dave ("LowEfficiency"): Initial model based on measured dimensions by David ("d-jones").
// v2: Dave ("LowEfficiency"): 3D-printing optimized "snap-in" variant added. (Concept only - not fit tested!)
// Constants:
inchesToMillimeters = 25.4; //Conversion factor
// Measured dimensions (converted to metric for model):
r1 = (1.05/2-0.037) * inchesToMillimeters; //Inner cutout
r2 = (1.05/2) * inchesToMillimeters; //Outer edge of inset surface that protrudes through metal tub cover
r3 = (1.215/2) * inchesToMillimeters; //Top surface flange of the window
windowThickness = 0.050 * inchesToMillimeters;
protrusionDepth = (0.227-0.050) * inchesToMillimeters;
// Calculated dimensions:
// * Shape is assumed to be a pill-shape with perfect half-circle ends
// * Spacing of rounded end center points is equal to the total length minus the end radius*2
// * Using outer edge of inset portion for calculation, as that is the surface profile that matters for tub fitment
circleCenterSpacing = (2.045 * inchesToMillimeters) - r2*2;
// Unusued dimensions:
// * Measured total length of window at flange is 2.218".
// * Calculated total length of window at flange, assuming perfectly circular ends, would be 2.045+((1.215-1.05)/2) = 2.1275"
// * This should be plenty close enough for a part that isn't fit-critical, and simplifies the model to use an equal flange width.
// * (Can be easily changed in the future if desired.)
// Modifiable parameters:
roundness = 120; //Number of facets to use for circle generation. Larger value = smoother. (Should always be a multiple of 4).
// Note: Some consumer 3D printer controllers/firmwares will stutter if given too many tiny segments. If this happens, reduce the number of facets.
// Part Seletion:
generateWindowFactoryDimensions = false;
generateWindowClipIn = true; //A more optimized clip-in part that doesn't need heat-bending or sealant to install
if (generateWindowFactoryDimensions == true)
{
window_FactoryDimensions();
}
if (generateWindowClipIn == true)
{
window_ClipIn();
}
module window_FactoryDimensions()
{
//Window surface and flange
hull()
{
cylinder(windowThickness, r3, r3, false, $fn=roundness);
translate([circleCenterSpacing, 0, 0])
cylinder(windowThickness, r3, r3, false, $fn=roundness);
}
//Window mounting protrusion
difference()
{
//Outer dimensions, overlapping window surface by 0.1 to ensure a solid model
translate([0,0,windowThickness-0.1])
hull()
{
cylinder(0.1+protrusionDepth, r2, r2, false, $fn=roundness);
translate([circleCenterSpacing, 0, 0])
cylinder(0.1+protrusionDepth, r2, r2, false, $fn=roundness);
}
//Inner cutout, overlapping on both ends to ensure a complete cut through without co-planar surfaces
// (This does not cut into the window surface, only the protrusion portion)
translate([0,0,windowThickness-0.1])
hull()
{
cylinder(0.1+protrusionDepth+1, r1, r1, false, $fn=roundness);
translate([circleCenterSpacing, 0, 0])
cylinder(0.1+protrusionDepth+1, r1, r1, false, $fn=roundness);
}
}
}
module window_ClipIn()
{
//Create a clip-in lens by modifying the "factory" version
//Modifiable variables:
slotWidth = 0.5; //Make larger if specific 3D printer tolerances require (ie: if gaps are too close and become connected)
tabWidth = 6;
tabBumpRadius = 0.8;
difference()
{
//Start with the factory shape
window_FactoryDimensions();
//Cut slots to create tabs, facilitating flexing
translate([0,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
translate([circleCenterSpacing-slotWidth,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
translate([slotWidth+tabWidth,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
translate([circleCenterSpacing-slotWidth-tabWidth-slotWidth,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
}
//Add the pill-shaped bumps
pillShapedBump(slotWidth, -r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
pillShapedBump(circleCenterSpacing-slotWidth-tabWidth, r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
pillShapedBump(circleCenterSpacing-slotWidth-tabWidth, -r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
pillShapedBump(slotWidth, r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
}
module pillShapedBump(xPosEdge, yPosCenter, zPosCenter, radius, length)
{
translate([xPosEdge+radius,yPosCenter,zPosCenter])
sphere(radius, $fn=32);
translate([xPosEdge+radius,yPosCenter,zPosCenter])
rotate([0,90,0])
cylinder(length-radius*2, radius, radius, false, $fn=32);
translate([xPosEdge+length-radius,yPosCenter,zPosCenter])
sphere(radius, $fn=32);
}
// ===================================================================================
// Replacement Maytag A806 Washing Machine Tub Light Window
// (Maytag Part Number 211723)
// See this formum thread for details:
// "Maytag tub light window A806"
// https://www.automaticwasher.org/cgi-bin/TD/TD-VIEWTHREAD.cgi?81875_15~1
// ===================================================================================
// Model version: 2
// Change log:
// v1: Dave ("LowEfficiency"): Initial model based on measured dimensions by David ("d-jones").
// v2: Dave ("LowEfficiency"): 3D-printing optimized "snap-in" variant added. (Concept only - not fit tested!)
// Constants:
inchesToMillimeters = 25.4; //Conversion factor
// Measured dimensions (converted to metric for model):
r1 = (1.05/2-0.037) * inchesToMillimeters; //Inner cutout
r2 = (1.05/2) * inchesToMillimeters; //Outer edge of inset surface that protrudes through metal tub cover
r3 = (1.215/2) * inchesToMillimeters; //Top surface flange of the window
windowThickness = 0.050 * inchesToMillimeters;
protrusionDepth = (0.227-0.050) * inchesToMillimeters;
// Calculated dimensions:
// * Shape is assumed to be a pill-shape with perfect half-circle ends
// * Spacing of rounded end center points is equal to the total length minus the end radius*2
// * Using outer edge of inset portion for calculation, as that is the surface profile that matters for tub fitment
circleCenterSpacing = (2.045 * inchesToMillimeters) - r2*2;
// Unusued dimensions:
// * Measured total length of window at flange is 2.218".
// * Calculated total length of window at flange, assuming perfectly circular ends, would be 2.045+((1.215-1.05)/2) = 2.1275"
// * This should be plenty close enough for a part that isn't fit-critical, and simplifies the model to use an equal flange width.
// * (Can be easily changed in the future if desired.)
// Modifiable parameters:
roundness = 120; //Number of facets to use for circle generation. Larger value = smoother. (Should always be a multiple of 4).
// Note: Some consumer 3D printer controllers/firmwares will stutter if given too many tiny segments. If this happens, reduce the number of facets.
// Part Seletion:
generateWindowFactoryDimensions = false;
generateWindowClipIn = true; //A more optimized clip-in part that doesn't need heat-bending or sealant to install
if (generateWindowFactoryDimensions == true)
{
window_FactoryDimensions();
}
if (generateWindowClipIn == true)
{
window_ClipIn();
}
module window_FactoryDimensions()
{
//Window surface and flange
hull()
{
cylinder(windowThickness, r3, r3, false, $fn=roundness);
translate([circleCenterSpacing, 0, 0])
cylinder(windowThickness, r3, r3, false, $fn=roundness);
}
//Window mounting protrusion
difference()
{
//Outer dimensions, overlapping window surface by 0.1 to ensure a solid model
translate([0,0,windowThickness-0.1])
hull()
{
cylinder(0.1+protrusionDepth, r2, r2, false, $fn=roundness);
translate([circleCenterSpacing, 0, 0])
cylinder(0.1+protrusionDepth, r2, r2, false, $fn=roundness);
}
//Inner cutout, overlapping on both ends to ensure a complete cut through without co-planar surfaces
// (This does not cut into the window surface, only the protrusion portion)
translate([0,0,windowThickness-0.1])
hull()
{
cylinder(0.1+protrusionDepth+1, r1, r1, false, $fn=roundness);
translate([circleCenterSpacing, 0, 0])
cylinder(0.1+protrusionDepth+1, r1, r1, false, $fn=roundness);
}
}
}
module window_ClipIn()
{
//Create a clip-in lens by modifying the "factory" version
//Modifiable variables:
slotWidth = 0.5; //Make larger if specific 3D printer tolerances require (ie: if gaps are too close and become connected)
tabWidth = 6;
tabBumpRadius = 0.8;
difference()
{
//Start with the factory shape
window_FactoryDimensions();
//Cut slots to create tabs, facilitating flexing
translate([0,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
translate([circleCenterSpacing-slotWidth,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
translate([slotWidth+tabWidth,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
translate([circleCenterSpacing-slotWidth-tabWidth-slotWidth,-r2-1,windowThickness+0.5])
cube([slotWidth,r2*2+2,protrusionDepth]);
}
//Add the pill-shaped bumps
pillShapedBump(slotWidth, -r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
pillShapedBump(circleCenterSpacing-slotWidth-tabWidth, r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
pillShapedBump(circleCenterSpacing-slotWidth-tabWidth, -r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
pillShapedBump(slotWidth, r2, windowThickness+protrusionDepth-tabBumpRadius, tabBumpRadius, tabWidth);
}
module pillShapedBump(xPosEdge, yPosCenter, zPosCenter, radius, length)
{
translate([xPosEdge+radius,yPosCenter,zPosCenter])
sphere(radius, $fn=32);
translate([xPosEdge+radius,yPosCenter,zPosCenter])
rotate([0,90,0])
cylinder(length-radius*2, radius, radius, false, $fn=32);
translate([xPosEdge+length-radius,yPosCenter,zPosCenter])
sphere(radius, $fn=32);
}
MT Tub Cover Light Lens
Very cool Dave, you just do not want it to protrude much below the tub cover as clothing sometimes is slung into that area with large loads during spin-drain.
This is why MT changed the " U " hose that the water enters through to have a light gray rubber end where it goes through the tub cover because the earlier all black rubber " U " hose would sometimes leave black stains on clothing.
Very cool Dave, you just do not want it to protrude much below the tub cover as clothing sometimes is slung into that area with large loads during spin-drain.
This is why MT changed the " U " hose that the water enters through to have a light gray rubber end where it goes through the tub cover because the earlier all black rubber " U " hose would sometimes leave black stains on clothing.
Nice work Dave!
I've been playing around in Tinkercad, which is a very basic program using starter point shapes, and as my CAD knowledge is even more basic I haven't gotten very far on it. I can't get my cubes to have rounded corners and the ovals are much too rounded to make the true pill shape.
I've thought for a long time if I could ever find a replacement lens I would cast it with a mold and clear resin, to make a very scarce part available to anyone else that might need one.
[this post was last edited: 2/15/2020-16:44]
I've been playing around in Tinkercad, which is a very basic program using starter point shapes, and as my CAD knowledge is even more basic I haven't gotten very far on it. I can't get my cubes to have rounded corners and the ovals are much too rounded to make the true pill shape.
I've thought for a long time if I could ever find a replacement lens I would cast it with a mold and clear resin, to make a very scarce part available to anyone else that might need one.
[this post was last edited: 2/15/2020-16:44]
Hmmm... Thinking some more about this...
The factory installation looks very secure. How does it come to be that windows go missing? Do they crack and fall out with age? Are a number of people missing their windows?
John and David make good points about the protrusion length and snagging possibility. If you were willing to use a sealant to fix it in place, I wonder if you could simply shorten the protrusion to say 25% of its length, and then glue it in place from the top with some clear silicone or the like? The protrusion would then simply serve to locate it horizontally, it wouldn't stick out much (if any) below the bottom of the metal.
Although not quite as original, another repair option might be to produce a smaller completely flat pill-shaped piece (which could be laser cut from sheet plexiglass or the like), and install flush into the opening with a small H-shaped rubber gasket around the perimeter.
The factory installation looks very secure. How does it come to be that windows go missing? Do they crack and fall out with age? Are a number of people missing their windows?
John and David make good points about the protrusion length and snagging possibility. If you were willing to use a sealant to fix it in place, I wonder if you could simply shorten the protrusion to say 25% of its length, and then glue it in place from the top with some clear silicone or the like? The protrusion would then simply serve to locate it horizontally, it wouldn't stick out much (if any) below the bottom of the metal.
Although not quite as original, another repair option might be to produce a smaller completely flat pill-shaped piece (which could be laser cut from sheet plexiglass or the like), and install flush into the opening with a small H-shaped rubber gasket around the perimeter.
tub window thread... back from the dead
[COLOR=#ff00ff; font-size: 10pt]A few years old now, I think with Covid Lockdown happening just weeks after this discussion was going on, I know I got distracted on the project. I recently found a 211723 window on eBay after years and years of having it in my saved searches notifications, and it led me back to this thread and an update I meant to post long ago. [/COLOR]
I personally never found a way to try 3D printing a new window for my tub, by way of all the excellent content posted above, but, using d-jones drawing I did eventually have some flat, clear acrylic lenses cut to the correct dimensions of the larger section of the lens.
It's just a basic plexiglass 'pill shape' that I siliconed to the top of the tub's light window port. Worked nicely and looked pretty good. I had them made by an Etsy seller that offered custom laser cut shapes, maybe 3 years ago. Because of how their store listed items, I had to get a lot consisting of at least 25, so a lot of extras.
I always thought I would offer the extras here on the site to anyone that came up needing one to restore a tub, but I hesitated because I wasn't 100% sure just how close they came to the original. Now that I have one for comparison it reminded me of the extra's, and my original idea... and turns out they are pretty spot on.
The main difference is the thickness of the lip of the main piece on the original compared to the thickness of the flat of the new; original is slightly thinner (0.50" compared to 1/16 inch or 0.625") you can see in the pictures. They are brand new and still covered with the protective cling film.
If anyone needs one, it's fine to message here, or my email is in my profile, hope this is helpful.
[COLOR=#ff00ff; font-size: 10pt]A few years old now, I think with Covid Lockdown happening just weeks after this discussion was going on, I know I got distracted on the project. I recently found a 211723 window on eBay after years and years of having it in my saved searches notifications, and it led me back to this thread and an update I meant to post long ago. [/COLOR]
I personally never found a way to try 3D printing a new window for my tub, by way of all the excellent content posted above, but, using d-jones drawing I did eventually have some flat, clear acrylic lenses cut to the correct dimensions of the larger section of the lens.
It's just a basic plexiglass 'pill shape' that I siliconed to the top of the tub's light window port. Worked nicely and looked pretty good. I had them made by an Etsy seller that offered custom laser cut shapes, maybe 3 years ago. Because of how their store listed items, I had to get a lot consisting of at least 25, so a lot of extras.
I always thought I would offer the extras here on the site to anyone that came up needing one to restore a tub, but I hesitated because I wasn't 100% sure just how close they came to the original. Now that I have one for comparison it reminded me of the extra's, and my original idea... and turns out they are pretty spot on.
The main difference is the thickness of the lip of the main piece on the original compared to the thickness of the flat of the new; original is slightly thinner (0.50" compared to 1/16 inch or 0.625") you can see in the pictures. They are brand new and still covered with the protective cling film.
If anyone needs one, it's fine to message here, or my email is in my profile, hope this is helpful.
